Ejemplo

Aquí tiene un ejemplo de lo que se puede hacer con Visual DialogScript. El diálogo que se muestra a continuación es una utilidad 'touch' de Windows que establece las marcas de fecha y hora de un conjunto de archivos en el valor que usted especifique.

WinTouch, la utilidad

El programa usa arrastrar y soltar, así que basta con arrastrar los archivos que desea modificar hasta el cuadro de lista, introducir la fecha y la hora y pulsar Touch.

El código

TITLE WinTouch
DIALOG CREATE,WinTouch,-1,0,268,180,DRAGDROP,SAVEPOS
DIALOG ADD,TEXT,TEXT1,10,10,,,Files to touch:
DIALOG ADD,LIST,FileList,30,10,240,80
DIALOG ADD,TEXT,TEXT2,120,10,,,Date:
DIALOG ADD,TEXT,TEXT3,140,10,,,Time:
DIALOG ADD,EDIT,Date,120,40,60,,@datetime(ddddd)
DIALOG ADD,EDIT,Time,140,40,60,,@datetime(t)
DIALOG ADD,BUTTON,Touch,120,110,140,40,Touch!
DIALOG SHOW
:again
dialog disable,Touch
:evloop
wait event
goto @event()
:TouchBUTTON
list seek,FileList,0
repeat
%F = @item(FileList)
file setdate,%F,@dlgtext(time),@dlgtext(date)
list delete,FileList
until @zero(@count(FileList))
goto again
:DragDrop
list DROPFILES,FileList
dialog enable,Touch
goto evloop
:CLOSE
exit

Cómo funciona

Antes de nada, conviene señalar que si usa el Asistente de Diálogos para generar el programa tras diseñar el diálogo con el Editor de Diálogos, en realidad solo necesita escribir diez líneas de código de las 29 que tiene este programa en total.

El comando title simplemente establece el título de la aplicación. El comando dialog create define el propio diálogo y se crea con el Editor de Diálogos. La única modificación consiste en insertar las dos llamadas a la función @datetime en los dos elementos de diálogo EDIT, que fijan los dos campos de edición con la fecha y la hora iniciales. Los parámetros DRAGDROP y SAVEPOS indican que queremos que el programa responda a operaciones de arrastrar y soltar, y que queremos que el diálogo recuerde la última posición en la que lo colocamos en la pantalla.

El comando dialog disable desactiva el botón Touch, de modo que no se pueda pulsar si no hay archivos en la lista. Las líneas :again y :evloop son etiquetas. Las dos líneas que siguen a :evloop esperan a que ocurra algo (lo que se llama un evento) y luego saltan a una etiqueta cuyo nombre corresponde al tipo del evento. Hay tres tipos posibles de evento: TouchBUTTON, que ocurre cuando se pulsa el botón Touch; DRAGDROP, que ocurre cuando se produce una operación de arrastrar y soltar; y CLOSE, que ocurre cuando el usuario cierra el diálogo. DialogScript no distingue entre mayúsculas y minúsculas en el tratamiento de las etiquetas. Todas las etiquetas y el esqueleto del código de gestión de eventos los genera el Asistente de Diálogos, si lo usa, de modo que su única aportación es insertar algo de código tras las etiquetas de evento para definir qué se supone que debe hacer el programa.

El evento DRAGDROP se gestiona simplemente con el comando list DROPFILES,FileList, que añade los nombres de los archivos arrastrados y soltados al cuadro de lista. El programa vuelve entonces a :evloop para esperar el siguiente evento. Las seis líneas que siguen a :TouchBUTTON eliminan los nombres de archivo del cuadro de lista, uno a uno, y usan el comando file setdate para cambiar la fecha y la hora a las especificadas en los dos campos de edición. Una vez procesados todos, el programa vuelve a :again. La acción predeterminada para el evento CLOSE es salir del programa.

Ejecución de scripts

Las versiones Personal de Visual DialogScript están pensadas para escribir scripts que se ejecutarán en el mismo PC. Mediante el mecanismo de asociación de archivos integrado en Windows, al hacer doble clic en el icono de un script, este se ejecuta. Se incluye una herramienta que le permite crear iconos en el Menú Inicio para los scripts que cree.

Las versiones Standard y Professional pueden crear archivos ejecutables que se distribuyen con un motor de ejecución, de modo que puedan ejecutarse en PC que no tengan instalada una copia con licencia de Visual DialogScript. No es necesario pagar regalías para distribuir el motor de ejecución. Esto convierte a Visual DialogScript en la herramienta más rentable cuando hay que distribuir programas de script por toda una organización: la mayoría de los lenguajes batch de Windows deben licenciarse por sistema.

¿Tiene otras preguntas sobre la funcionalidad de Visual DialogScript? Visite la página de Soporte.